Slouching Towards Bedlam — 54 of 76

Section 7(d) - Reginald

Reginald is a man who is part of the hansom cab. Understand "Reggie", "Maundy", "driver", "man" and "coachman" as Reginald. The description of Reginald is "An older gentleman, skin tanned and wrinkled. He wears both a hat and an easy grin." The analysis of Reginald is "CAT:LIVING.HUMAN[line break]MALE.UTIL:COMMUN[line break]ICATION.POSSIBLE[line break]BY.SPEECH.OR.WRI[line break]TTEN.WORD.PART:I[line break]D=REGINALD.MAUND[line break]Y.POSITION:HANSO[line break]M.CAB.OPERATOR.." Understand "corpse" as Reginald when Reginald is dead.

Instead of attacking Reginald:

now Reginald is dead;

now the description of Reginald is "The corpse lies crumpled against the alley's wall.";

now the printed name of Reginald is "Reggie's corpse";

now the initial appearance of Reginald is "Reggie's corpse is here.";

say "A false destination. It is as easy as that.[paragraph break]The cab turns down a vacant alley that ends in a wall. It goes fast at first. Reggie yelps in surprise as the gloved fingers close around his throat. He thrashes, but he is old and can not overtake the grip that holds him fast.[paragraph break]The most he manages is to turn around and stare with surprised, horrified eyes, his fingers clutching his throat, desperate to make room for air.[paragraph break]It does not take long for the life to slide from behind his eyes turning them to glass. Even still the fingers keep gripping, one, two minutes more to be sure. When they let go, Reggie's body slumps and falls to the ground.[paragraph break]There is a sickening thud as bones break on impact and the carriage rolls to a stop...";

if Triage is visible and the emerald is switched on, move Triage to Alley;

move Reginald to Alley;

move the hansom cab to Alley;

move the player to Alley;

spur on the Logos;

Alley is a room. The description of Alley is "A narrow space between walls, barely enough for the cab to navigate."

Instead of going nowhere from Alley:

if the noun is west or the noun is east or the noun is south:

say "A wall blocks the way.";

otherwise if the noun is north:

say "The cab blocks the way.";

otherwise:

continue the action;

Driving is an action applying to one visible thing. Understand "drive [something]" as driving. Instead of driving something that is not the hansom cab, say "That cannot be driven." Instead of driving the hansom cab, say "To where, specifically?" Understand "drive the cab to [text]", "drive cab to [text]", "drive hansom cab to [text]", "drive the hansom cab to [text]" as travelling to.